つなぐだけでトースターが自動リフローオーブンになるコントローラーを作ろう

#include <SPI.h>
#include <LiquidCrystal.h>
#include <PID_v1.h>
//#include SERIAL_MON
#define VCC  8
#define GND  9
#define SLAVE 10
// LCD
const int rs = 2, en = 3, d4 = 4, d5 = 5, d6 = 6, d7 = 7;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);
// LED
bool state_led_buitlin = false;
// 温度閾値の設定
double thermo_preheat = 90;
double thermo_preheat_done = 130;
double thermo_max = 180;
// 熱電対
float thermo_now=0; // 熱電対温度
// PID変数
double setpoint = 0;
double input, output;
PID myPID(&input, &output, &setpoint,15,0,0, DIRECT);
// タイマー
unsigned int time_start = 0, time_now = 0, time_start_for_serial = 0;
// SSR
const int SSR = A5;
// SW
const int SW = A3;
// PWM
unsigned long pwm_period = 1000;  // PWM period in milliseconds
unsigned long last_switch_time;
// Phase
unsigned int phase=0;
#define PHASE0 0  //開始前
#define PHASE1 1  // 開始 - preheat
#define PHASE2 2  // preheat
#define PHASE3 3  // preheat - max
#define PHASE4 4  // 終了
int duration_phase1 = 90;
int duration_phase2 = 90;
int duration_phase3 = 60;
void setup() {
#ifdef GND
pinMode(GND, OUTPUT);
digitalWrite(GND, LOW);
#endif
#ifdef VCC
pinMode(VCC, OUTPUT);
digitalWrite(VCC, HIGH);
#endif
pinMode(SLAVE, OUTPUT);
digitalWrite(SLAVE, HIGH);
Serial.begin(9600);
SPI.begin();
SPI.setBitOrder(MSBFIRST);
SPI.setClockDivider(SPI_CLOCK_DIV4);
SPI.setDataMode(SPI_MODE0);
// set up the LCD's number of columns and rows:
lcd.begin(16, 2);
// LED pin settings
pinMode(LED_BUILTIN, OUTPUT);
digitalWrite(LED_BUILTIN, LOW);
// SW
pinMode(SW, INPUT);
// PID settings
myPID.SetMode(AUTOMATIC);
myPID.SetOutputLimits(0, 255);
// SSR
pinMode(SSR, OUTPUT);
time_start = millis() / 1000;
last_switch_time = millis();
phase = PHASE0;
}
void loop() {
unsigned int thermocouple; // 14-Bit Thermocouple Temperature Data + 2-Bit
unsigned int internal; // 12-Bit Internal Temperature Data + 4-Bit
time_now = millis() / 1000;
// State machine
switch(phase){
case PHASE0:
if(digitalRead(SW)){
delay(10);   // チャタリング対策。値は適当。
if(digitalRead(SW)){
while(digitalRead(SW)){
lcd.clear();
lcd.setCursor(0,0);
lcd.print("START!");
delay(1000);
}
phase = PHASE1;
time_start = millis() / 1000;   //タイマーリセット
setpoint = thermo_preheat;
myPID.SetTunings(15,0,0);         // Kp, Ki, Kd を調整
lcd.clear();
delay(10);
}
}
break;
case PHASE1:
if(thermo_now > thermo_preheat-2 ){
if((time_now - time_start)> duration_phase1){
phase = PHASE2;
time_start = millis() / 1000;   //タイマーリセット
setpoint = thermo_preheat_done;
myPID.SetTunings(5,0,0);         // Kp, Ki, Kd を調整
lcd.clear();
}else{
setpoint = 0;     // 早く温度が上がりすぎた場合は待機
}
}
break;
case PHASE2:
if(thermo_now > thermo_preheat_done-2){
if((time_now - time_start)>duration_phase2){
phase = PHASE3;
setpoint = thermo_max;                 // プロファイル上は165だけど、マージンを見て180とする。
myPID.SetTunings(15,0,0);         // Kp, Ki, Kd を調整
time_start = millis() / 1000;   // タイマーリセット
lcd.clear();
} else{
setpoint = 0;     // 早く温度が上がりすぎた場合は待機
}
}
break;
case PHASE3:
if(thermo_now>thermo_max-2){
if((time_now - time_start)>duration_phase3){
phase = PHASE4;
setpoint = 0;
time_start = millis() / 1000;   // タイマーリセット
lcd.clear();
} else{
setpoint = 0;
}
}
break;
case PHASE4:
state_led_buitlin = !state_led_buitlin;
digitalWrite(LED_BUILTIN, state_led_buitlin);
setpoint = 0;
if(digitalRead(SW)){
delay(10);   // チャタリング対策。値は適当。
if(digitalRead(SW)){
phase = PHASE0;
while(digitalRead(SW)){
lcd.clear();
lcd.setCursor(0,0);
lcd.print("RESET!");
delay(1000);
}
lcd.clear();
time_start = millis() / 1000;   // タイマーリセット
}
}
}
digitalWrite(SLAVE, LOW);                             //  Enable the chip
thermocouple = (unsigned int)SPI.transfer(0x00) << 8;   //  Read high byte thermocouple
thermocouple |= (unsigned int)SPI.transfer(0x00);       //  Read low byte thermocouple
internal = (unsigned int)SPI.transfer(0x00) << 8;       //  Read high byte internal
internal |= (unsigned int)SPI.transfer(0x00);           //  Read low byte internal
digitalWrite(SLAVE, HIGH);                            //  Disable the chip
if((thermocouple & 0x0001) != 0) {
//    Serial.print("ERROR: ");
//    if ((internal & 0x0004) !=0) {
//      Serial.print("Short to Vcc, ");
//    }
//    if ((internal & 0x0002) !=0) {
//      Serial.print("Short to GND, ");
//    }
//    if ((internal & 0x0001) !=0) {
//      Serial.print("Open Circuit, ");
//    }
//    Serial.println();
} else {
if((thermocouple & 0x8000) == 0){ // 0℃以上   above 0 Degrees Celsius
thermo_now = (thermocouple >> 2) * 0.25;
} else {                          // 0℃未満   below zero
thermo_now = (0x3fff - (thermocouple >> 2) + 1)  * -0.25;
}
// PWM
unsigned long current_time = millis();
unsigned long time_since_last_switch = current_time - last_switch_time;
double duty_cycle = output/255;
unsigned long on_time = pwm_period * duty_cycle;
if(time_since_last_switch >= pwm_period && duty_cycle > 0){
// Start a new PWM cycle
digitalWrite(SSR, HIGH);
last_switch_time = current_time;
} else if (time_since_last_switch >= on_time){
digitalWrite(SSR, LOW);
}
// PID controll
input = thermo_now;
myPID.Compute();
// serial plot
if(time_start_for_serial-time_now >= 1){
Serial.print("0,250,");     //縦軸固定
Serial.print(thermo_now);
Serial.print(",");
Serial.println(setpoint);
#ifdef SERIAL_MON
Serial.print(thermocouple, HEX);
Serial.print(" : ");
Serial.print(thermo_now);
Serial.print(" // ");
#endif
time_start_for_serial = millis() / 1000;   // タイマーリセット
}
// display LCD
switch(phase){
case PHASE0:
lcd.setCursor(0, 0);
lcd.print("Themo:");
lcd.setCursor(7, 0);
lcd.print(thermo_now);
lcd.setCursor(13,0);
lcd.print("degC");
lcd.setCursor(0, 1);
lcd.print("PUSH SW TO START");
break;
case PHASE1:
case PHASE2:
case PHASE3:
case PHASE4:
lcd.setCursor(0, 0);
lcd.print("Themo:");
lcd.setCursor(7, 0);
lcd.print(thermo_now);
lcd.setCursor(13,0);
lcd.print("degC");
lcd.setCursor(0, 1);
lcd.print("Phase");
lcd.setCursor(5, 1);
lcd.print(phase);
lcd.setCursor(11, 1);
lcd.print(time_now-time_start);
lcd.setCursor(15,1);
lcd.print("s");
break;
}
}
}